@AbapCatalog.sqlViewName: 'ZVTAX0020'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: '사업자카드사용경비처리이력'
@Metadata.ignorePropagatedAnnotations: true
define view zcds_tax0020
  as select
    key p.gjahr,
    key p.quarter,
    key p.reg_no,
        p.confirm_date,
        q.card_company,
        p.card_no,
        p.shop_reg_no,
        p.shop_nm,
        @Semantics.currencyCode: true
        p.waers,
        @Semantics.amount.currencyCode: 'waers'
        p.supply_value,
        @Semantics.amount.currencyCode: 'waers'
        p.tax_amount,
        @Semantics.amount.currencyCode: 'waers'
        p.non_taxable,
        @Semantics.amount.currencyCode: 'waers'
        p.amount_supply,
        p.shop_type,
        cast ( case p.shop_type
         when '01' then '법인사업자'
         when '02' then '일반과세자'
         when '03' then '면세사업자'
         when '04' then '간이과세자'
         else ''
         end as abap.char(10) )                                               as shop_ty_name,
        p.bisiness_type,
        p.bisiness_category,
        cast( COALESCE(r.deduction_status, p.deduction_status) as zdedstatus) as deduction_status,
        cast( case COALESCE(r.deduction_status, p.deduction_status)
         when '01' then '불공제'
         when '02' then '공제'
         else ''
        end as abap.char(5) )                                                 as deduction_desc,
        p.etc,
        r.acct,
        t.code_txt  as acct_nm,
        f.code_txt  as gacct_nm,
        r.origin,
        s.code_txt as origin_nm,
        r.descript,
        r.export
  from              zttax0020 as p
    left outer join zttax0010 as q on p.card_no = q.card_no
    left outer join zttax0030 as r on  p.gjahr   = r.gjahr
                                   and p.quarter = r.quarter
                                   and p.reg_no  = r.reg_no
    left outer join zcat0020 as t
      on t.appli  = 'TX'
     and t.grp    = 'TAX01'
     and t.spras  = 'E'
     and t.code   = r.acct
    left outer join zcat0020 as s
      on s.appli    = 'TX'
     and s.grp      = 'TAX02'
     and s.spras    = 'E'
     and s.code     = r.origin
    left outer join zcat0020 as f
      on f.appli  = t.appli
     and f.grp    = t.grp
     and f.spras  = t.spras
     and f.code   = t.fld_02